台灣最大程式設計社群網站
線上人數
2032
 
會員總數:245254
討論主題:189112
歡迎您免費加入會員
討論區列表 >> ASP >> [ASP]我的計數器跑不出來
[]  
[我要回覆]
1
回應主題 加入我的關注話題 檢舉此篇討論 將提問者加入個人黑名單
[ASP]我的計數器跑不出來
價值 : 0 QP  點閱數:1705 回應數:10

樓主


初學者
16 2
0 6
發送站內信

我再網頁上自己設置一了一個圖形計數器......
他會出現
-------------------------
Microsoft VBScript 執行階段錯誤 錯誤 '800a0046' 

沒有使用權限 

/club/c40/a/FileCnt.fun, 列8 
--------------------------

我是放在http://stuoffice.thu.edu.tw/club/C40/

我是參考依本asp網頁製作較本王國榮寫的書做的
用了兩行
<!-- #include virtual="/club/c40/a/FileCnt.fun" --> 
<!-- #include virtual="/club/c40/a/Gcounter.fun" -->

在檔案/a/astivity.asp  的<html>前面呼叫

1.而FileCnt.fun裡面是
=======================================
<% ' FileCnt.fun: 訪客計數器, 檔案版本
Function kjFileCounter( counter_file )
    Dim fs, txt, file
    Application.Lock
    Set fs = Server.CreateObject("Scripting.FileSystemObject")
    file = Server.MapPath( counter_file )

    Set txt = fs.OpenTextFile( file, 1, True )
    If Not txt.atEndOfStream Then kjFileCounter = CLng(txt.ReadLine)
end if
    kjFileCounter = kjFileCounter + 1
    txt.Close

    On Error Resume Next
    Set txt = fs.CreateTextFile( file, True )
    If Err.Number = 70 Then
        kjFileCounter = "請先將 " & file & " 的唯讀屬性去除!"
    ElseIf Err.Number <> 0 Then
        kjFileCounter = Err.Description
    Else
       txt.WriteLine kjFileCounter
       txt.Close
    End If
    Application.UnLock
End Function


%>
======================================

2.而Gcounter.fun裡面是
======================================
<%
Function GCounter( counter )
   Dim S, i, G
   S = CStr( counter ) ' 先將數值轉成字串 S

   ' 逐一取字串S的每一個字元, 然後串成 <IMG SRC=?.jpg> 的圖形標示
   For i = 1 to Len(S)
      G = G & "<IMG SRC=/club/c40/a/number/" & Mid(S, i, 1) & ".jpg Align=TextTop>"
   Next
   GCounter = G
End Function
%>
====================================

3.
astivityasp
除了在<HTML>前加上兩行呼叫程式外
在放計數器哪裡我用了
<%=GCounter(kjFileCounter("/club/c40/counter.txt"))%>

++++++++++++++++++++++++++++++++++++

我希望可以自計作計數器.....
不希望外面去申請.........
所以 希望請知道我出了啥問題人跟我說一聲.......

再備註一點........
我在自己電腦裡pws瀏覽沒有問題........
(當然位置我有改啦)
放到學校上面去時.......
學校我我的網址連結是
http://stuoffice.thu.edu.tw/club/C40/

所以我才把一些地方改成/club/C40/XXXX

可是就跑不出來了.....

拜託誰來救救我啊!!!!!!!!
感激不盡...
                                             想為彰友架一個網頁的MN留

搜尋相關Tags的文章: [ 計數器 ] ,
本篇文章發表於2002-05-11 17:55
別忘捐VP感謝幫助你的人 新手會員瞧一瞧
1樓
回應

路人乙
檢舉此回應
它說-------------> /club/c40/a/FileCnt.fun, 列8 
那應該是----------------------->    Set txt = fs.OpenTextFile( file, 1, True )
這行有問題吧?
也許你忘了連結王國榮的DB.FUN了吧?
本篇文章回覆於2002-05-12 09:05
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
2樓
作者回應


檢舉此回應
我暫時改了一下連結.......
http://stuoffice.thu.edu.tw/club/C40/a/activity1.asp
希望能實際去看一下.....


為何在我的電腦pws下又不會有問題.....
是不是學校亂設啥權限.......
所以導致計數器.留言板.會員資料申請...等會需要存取資料的網頁都沒辦法運作勒....
不過應該不至於這樣吧....


:<<<路人乙曰>>>
:它說-------------> /club/c40/a/FileCnt.fun, 列8 
:那應該是----------------------->    Set txt = fs.OpenTextFile( file, 1, True )
:這行有問題吧?
:也許你忘了連結王國榮的DB.FUN了吧?
-------------------------------------------------

的確是沒有......
且我在他書中第七章('物件與網頁製作應用)也找不如何連結DB.fun----
他的內容有....
粉長一段....
都會用的到嗎???
我該怎麼作連結捏?????
有聯連結DB.FUN後有沒有哪裡路進需要修改的捏???


=====================================================
<%
'---------------------------------------------------
Function GetMdbConnection( FileName )
   Dim Provider, DBPath

   Provider = "Provider=Microsoft.Jet.OLEDB.4.0;"
   DBPath = "Data Source=" & Server.MapPath(FileName)
   Set GetMdbConnection = GetConnection( Provider & DBPath )
End Function

'---------------------------------------------------
Function GetSecuredMdbConnection( FileName, Password )
   Dim Provider, DBPath

   Provider = "Provider=Microsoft.Jet.OLEDB.4.0;"
   DBPath = "Data Source=" & Server.MapPath(FileName)
   Set GetSecuredMdbConnection = GetConnection( Provider & DBPath & ";Jet OLEDB:Database Password=" & Password )
End Function

'---------------------------------------------------
Function GetDbcConnection( FileName )
   Dim Driver, SourceType, DBPath

   Driver = "Driver={Microsoft Visual FoxPro Driver};"
   SourceType = "SourceType=DBC;"
   DBPath = "SourceDB=" & Server.MapPath( FileName )
   Set GetDbcConnection = GetConnection( Driver & SourceType & DBPath )
End Function

'---------------------------------------------------
Function GetDbfConnection( Directory )
   Dim Driver, SourceType, DBPath

   Driver = "Driver={Microsoft Visual FoxPro Driver};"
   SourceType = "SourceType=DBF;"
   DBPath = "SourceDB=" & Server.MapPath( Directory )
   Set GetDbfConnection = GetConnection( Driver & SourceType & DBPath )
End Function

'---------------------------------------------------
Function GetExcelConnection( FileName )
   Dim Driver, DBPath

   Driver = "Driver={Microsoft Excel Driver (*.xls)};"
   DBPath = "DBQ=" & Server.MapPath( FileName )
   Set GetExcelConnection = GetConnection( Driver & "ReadOnly=0;" & DBPath )
End Function

'---------------------------------------------------
Function GetTextConnection( Directory )
   Dim Driver, DBPath

   Driver = "Driver={Microsoft Text Driver (*.txt; *.csv)};"
   DBPath = "DBQ=" & Server.MapPath( Directory )
   Set GetTextConnection = GetConnection( Driver & DBPath )
End Function

'---------------------------------------------------
Function GetSQLServerConnection( Computer, UserID, Password, Db )
   Dim Params, conn
   
   Set GetSQLServerConnection = Nothing
   Params = "Provider=SQLOLEDB.1"
   Params = Params & ";Data Source=" & Computer
   Params = Params & ";User ID=" & UserID
   Params = Params & ";Password=" & Password
   Params = Params & ";Initial Catalog=" & Db
   Set conn = Server.CreateObject("ADODB.Connection")
   conn.Open Params
   Set GetSQLServerConnection = conn
End Function

'---------------------------------------------------
Function GetMdbRecordset( FileName, Source )
   Set GetMdbRecordset = GetMdbRs( FileName, Source, 2, "" )
End Function

'---------------------------------------------------
Function GetMdbStaticRecordset( FileName, Source )
   Set GetMdbStaticRecordset = GetMdbRs( FileName, Source, 3, "" )
End Function

'---------------------------------------------------
Function GetSecuredMdbRecordset( FileName, Source, Password )
   Set GetSecuredMdbRecordset = GetMdbRs( FileName, Source, 2, Password )
End Function

'---------------------------------------------------
Function GetSecuredMdbStaticRecordset( FileName, Source, Password )
   Set GetSecuredMdbStaticRecordset = GetMdbRs( FileName, Source, 3, Password )
End Function

'---------------------------------------------------
Function GetDbfRecordset( Directory, SQL )
   Set GetDbfRecordset = GetOtherRs( "Dbf", Directory, SQL, 2 )
End Function

'---------------------------------------------------
Function GetDbfStaticRecordset( Directory, SQL )
   Set GetDbfStaticRecordset = GetOtherRs( "Dbf", Directory, SQL, 3 )
End Function

'---------------------------------------------------
Function GetDbcRecordset( FileName, SQL )
   Set GetDbcRecordset = GetOtherRs( "Dbc", FileName, SQL, 2 )
End Function

'---------------------------------------------------
Function GetDbcStaticRecordset( FileName, SQL )
   Set GetDbcStaticRecordset = GetOtherRs( "Dbc", FileName, SQL, 3 )
End Function

'---------------------------------------------------
Function GetExcelRecordset( FileName, SQL )
   Set GetExcelRecordset = GetOtherRs( "Excel", FileName, SQL, 2 )
End Function

'---------------------------------------------------
Function GetExcelStaticRecordset( FileName, SQL )
   Set GetExcelStaticRecordset = GetOtherRs( "Excel", FileName, SQL, 3 )
End Function

'---------------------------------------------------
Function GetTextRecordset( Directory, SQL )
   Set GetTextRecordset = GetOtherRs( "Text", Directory, SQL, 2 )
End Function

'---------------------------------------------------
Function GetTextStaticRecordset( Directory, SQL )
   Set GetTextStaticRecordset = GetOtherRs( "Text", Directory, SQL, 3 )
End Function

'---------------------------------------------------
Function GetSQLServerRecordset( conn, source )
   Dim rs

   Set rs = Server.CreateObject("ADODB.Recordset")
   rs.Open source, conn, 2, 2
   Set GetSQLServerRecordset = rs
End Function

'---------------------------------------------------
Function GetSQLServerStaticRecordset( conn, source )
   Dim rs

   Set rs = Server.CreateObject("ADODB.Recordset")
   rs.Open source, conn, 3, 2
   Set GetSQLServerStaticRecordset = rs
End Function

'---------------------------------------------------
Function GetConnection( Param )
   Dim conn 

   On Error Resume Next
   Set GetConnection = Nothing
   Set conn = Server.CreateObject("ADODB.Connection")
   If Err.Number <> 0 Then Exit Function

   conn.Open Param
   If Err.Number <> 0 Then Exit Function
   Set GetConnection = conn
End Function

'---------------------------------------------------
Function GetMdbRs( FileName, Source, Cursor, Password )
   Dim conn, rs

   On Error Resume Next
   Set GetMdbRs = Nothing
   If Len(Password) = 0 Then
       Set conn = GetMdbConnection( FileName )
   Else
       Set conn = GetSecuredMdbConnection( FileName, Password )
   End If
   If conn Is Nothing Then Exit Function

   Set rs = Server.CreateObject("ADODB.Recordset")
   If Err.Number <> 0 Then Exit Function

   rs.Open source, conn, Cursor, 2
   If Err.Number <> 0 Then Exit Function
   Set GetMdbRs = rs
End Function

'---------------------------------------------------
Function GetOtherRs( DataType, Path, SQL, Cursor )
   Dim conn, rs
   On Error Resume Next
   Set GetOtherRs = Nothing

   Select Case DataType
      Case "Dbf"
         Set conn = GetDbfConnection( Path )
      Case "Dbc"
         Set conn = GetDbcConnection( Path )
      Case "Excel"
         Set conn = GetExcelConnection( Path )
      Case "Text"
         Set conn = GetTextConnection( Path )
   End Select
   If conn Is Nothing Then Exit Function

   Set rs = Server.CreateObject("ADODB.Recordset")
   If Err.Number <> 0 Then Exit Function

   rs.Open SQL, conn, Cursor, 2
   If Err.Number <> 0 Then Exit Function
   Set GetOtherRs = rs
End Function

'---------------------------------------------------
Function GetSQLServerRs( Computer, UserID, Password, Db, source, Cursor )
   Dim conn, rs

   On Error Resume Next
   Set GetSQLServerRs = Nothing
   Set conn = GetSQLServerConnection( Computer, UserID, Password, Db )
   If conn Is Nothing Then Exit Function

   Set rs = Server.CreateObject("ADODB.Recordset")
   If Err.Number <> 0 Then Exit Function

   rs.Open source, conn, Cursor, 2
   If Err.Number <> 0 Then Exit Function
   Set GetSQLServerRs = rs
End Function
%>

================================================
我粉希望保留計數器...........
誰來幫我啊...
本篇文章回覆於2002-05-12 11:35
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
3樓
回應

路人乙
檢舉此回應
喔  抱欠 我也是看你說的那王國榮的書 所以那個計數器範例也知
那個應該沒有用到資料庫 就不需db.fun了 搞錯了
那可能是伺服器的問題吧 … 那我的程度可能就無法解決摟 
請問你的電腦是用98 or NT OR XP ...?
NT 的話應該要管理員權限…
本篇文章回覆於2002-05-12 11:42
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
4樓
回應

路人乙
檢舉此回應
但如果要聯結的話就跟其他二個檔案一樣嘛 用include 呀
本篇文章回覆於2002-05-12 11:47
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
5樓
作者回應


檢舉此回應
不過我非常謝謝你的回應.....
我自己的電腦是的os是me...
學校的2000

這樣表示是學校server那邊的問題嚕.....
害人家第一次上傳時計數器.留言板都跑步出來...
好傷心喔....

如果是這樣的話.....
那表示應該不是我有寫錯的地方嚕...
如果還有誰可以肯定我哪裡寫錯希望回應一下......
如果覺得我都沒有寫錯的地方也請回應一下.......

我只好明天在去問問看嚕....
本篇文章回覆於2002-05-12 13:00
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
6樓
回應

星辰
檢舉此回應
將存放計數的文件打個數字0
問題就解決了
本篇文章回覆於2002-05-12 13:49
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
7樓
作者回應


檢舉此回應
我打上0之後...
且在幾ㄍ地方加上  /club/C40     
卻又發生下列狀況...
======================================
<IMG SRC=/club/C40/a/number/請.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/先.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/將.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/ .jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/H.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/:.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/\.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/c.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/l.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/u.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/b.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/\.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/c.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/4.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/0.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/\.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/c.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/o.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/u.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/n.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/t.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/e.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/r.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/..jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/t.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/x.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/t.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/ .jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/的.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/唯.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/讀.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/屬.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/性.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/去.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/除.jpg Align=TextTop>
<IMG SRC=/club/C40/a/number/!.jpg Align=TextTop>
==============================================
粉明顯.......
他是跑進...FileCnt.fun的第....16行...

這樣是不是就是說學校windows2000主機設定上怪怪的?????
不是我程式有寫錯嚕........??
是這樣嗎.....
如果是...
那我該怎樣跟學校老師說要開怎樣ㄉ權限..
才可以讓每ㄍ瀏覽網站的人都可以順利看到計數捏???
拜託再解答一下我ㄉ一問....
拜託拜託!!
本篇文章回覆於2002-05-12 18:10
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
8樓
回應

lgwlee
檢舉此回應
pws沒問題
IIS有問題~
是不是網頁權限的問題?
本篇文章回覆於2002-05-13 01:48
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
9樓
回應

Jyh
檢舉此回應
我有碰過類似的問題,我是因為紀錄人次的檔案放在唯讀區域,改放在
有寫入權限的資料夾就解決了.
如brinkster網頁,只有db資料夾可寫入,妳不妨查察權限問題
本篇文章回覆於2002-05-13 13:42
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
10樓
作者回應


檢舉此回應
謝謝大家的回應.......
讓我感覺到這個站的人都好熱情.
也好慷慨喔......
我後來去問過了.....
的確是被設定為無法寫入的關係........
現在已經OK嚕.....


http://stuoffice.thu.edu.tw/club/C40/

大家有空希望去看一下
也可以在給小弟一些寫網頁的建議啊......
在一次感激謝謝幫我解決問題的夥伴....
本篇文章回覆於2002-05-14 01:02
== 簽名檔 ==
--未登入的會員無法查看對方簽名檔--
   
1

回覆
如要回應,請先登入.