台灣最大程式設計社群網站
線上人數
768
 
會員總數:245608
討論主題:189311
歡迎您免費加入會員
討論區列表 >> 專欄文章 >> 在ASP應用中如何限制同一表單被多次提交
[]  
[我要回覆]
回應主題 加入我的關注話題 檢舉此篇討論 將提問者加入個人黑名單
在ASP應用中如何限制同一表單被多次提交
價值 : 0 QP  點閱數:778 回應數:0
樓主

站務人員 站長
門外漢
0 1580
542 9
發送站內信

捐贈 VP 給 站務人員
在ASP應用中如何限制同一表單被多次提交

在Internet上我們每天都會遇到數不清的表單,也看到其中大部分並沒有限制會員多次提交同一個表單.缺乏這種限制有時候會產生某些預料不到的結果,如重覆訂閱郵件服務或重覆投票等.

本文介紹在ASP應用中防止會員在目前會話期間多次提交同一表單的一個簡單方法.它主要由四個子程式組成,在較為簡單的應用場合,你隻要將這些代碼放在包含文件中直接引用即可;對於那些較為復雜的環境,我們在文章的最後給出一些改進建議.

一、基本工作過程
下面我們依次討論這四個子程式.

(一)初始化
這裡我們要在Session對象中保存兩個變量,其中:
每一個表單對應一個稱為FID的唯一標識,為使該值唯一要用到一個計數器.
每當一個表單成功提交,必須在一個Dictionary對象中存儲它的FID.
我們用一個專用的過程來初始化上述資料.雖然以後各個子程式都要調用它,但實際上每一個會話期間它隻執行一次: Sub InitializeFID()
If Not IsObject(Session("FIDList")) Then
Set Session("FIDList")=Server.CreateObject("Scripting.Dictionary")
Session("FID")=0
End If
End Sub

(二)產生表單的唯一標識符
下面這個函數GenerateFID()用於產生表單的唯一標志.該函數首先將FID值加1,然後返回它: Function GenerateFID()
InitializeFID
Session("FID") = Session("FID") + 1
GenerateFID = Session("FID")
End Function

(三)登記已提交表單
當表單成功地提交時,在Dictionary對象中登記它的唯一標識:
Sub RegisterFID()
Dim strFID
InitializeFID
strFID = Request("FID")
Session("FIDlist").Add strFID, now()
End Sub

(四)檢查表單是否重覆提交
在正式處理會員提交的表單之前,應該在Dictionary對象中檢查它的FID是否已經登記.下面的CheckFID()函數用來完成這個工作,如已經登記,它返回FALSE,否則返回TRUE: Function CheckFID()
Dim strFID
InitializeFID
strFID = Request("FID")
CheckFID = not Session("FIDlist").Exists(strFID)
End Function


二、如何使用
有兩個地方要用到上述函數,即表單產生時與結果處理時.假設上述四個子程式已經放入包含文件Forms.inc中,下面的代碼根據FID值來決定產生表單還是處理表單結果,它所描述的處理過程適合於大多數ASP應用: <%Option Explicit%>
<!--#include file="forms.inc"-->
<HTML>
<HEAD>
<TITLE>表單提交測試</TITLE>
</HEAD
<BODY>
<%
If Request("FID") = "" Then
GenerateForm
Else
ProcessForm
End If
%>
</BODY>
</HTML>

GenerateForm負責產生表單,表單中應該含有一個隱藏的FID,如: <%
Sub GenerateForm()
%>
<form action="<%=Request.ServerVariables("PATH_INFO")%>" method=GET>
<input type=hidden name=FID value="<%=GenerateFID()%>">
<input type=text name="param1" value="">
<input type=submit value="OK">
</form>
<%
End Sub
%>

ProcessForm負責處理通過表單提交的內容,但在處理之前應該先調用CheckFID()檢查目前表單是否已經提交,代碼類如: <%
Sub ProcessForm()
If CheckFID() Then
Response.Write "你輸入的內容是" & Request.QueryString("param1")
RegisterFID
Else
Response.Write "此表單隻能提交一次!"
End If
End Sub
%>

三、限制與改進措施
上面我們介紹了在目前會話期間限制同一表單被多次提交的一種方法.在實際應用中可能需要從多方面加以改進,例如:
在登記表單ID之前檢查會員輸入資料的合法性,使得資料不合法時會員可以按“後退”按鈕返回,在修正後再次提交同一表單.
這種對表單提交的限制最多隻能在目前會話期間有效.如果要求這種限制能夠跨越多個會話,那麼就要用到Cookeis或資料庫來保存相關資料了.
這種方法是不安全的.它僅用於防範誤操作,不能防止熟練會員有意地多次提交同一表單


--------------------------------------------------------------------------------

本篇文章發表於2002-06-09 00:00
目前尚無任何回覆
   

回覆
如要回應,請先登入.